我已经在这方面工作了一段时间，并让它与递归函数一起工作（这是我第一次尝试它，所以它可能不是“最佳”）和ofc与数组一起工作以提高速度。
无论是否使用BIG-sort值，排序都可以正常工作。如果有一个同名的团队，即使他们有BIG值，也要正确排序（最小的团队优先）。具有多个BIG值的团队获得上面排序的第一个大值，如果不同的团队具有相同的BIG值，则最小的团队首先出现（与其他团队一样）。

Option Explicit
Dim hasImportance_dic As Object
Dim funcIteration As Long

Sub RETEAM()
    Dim Data_dic As Object
    Set Data_dic = CreateObject("Scripting.Dictionary")
    Set hasImportance_dic = CreateObject("Scripting.Dictionary")
    Dim lRow As Long, arr, lRowV As Long, arrSort, amtSorted As Long
    Dim ws As Worksheet
    
    Set ws = ActiveWorkbook.Worksheets("team0")
    lRow = ws.Range("B" & Rows.Count).End(xlUp).row
    lRowV = ws.Range("V" & Rows.Count).End(xlUp).row
    arr = ws.Range("A2:C" & lRow).value
    If lRowV > 1 Then arrSort = ws.Range("V2:V" & lRowV).value
    
    Dim i As Long
    For i = 1 To UBound(arr, 1) 'counting the teams
        If Not Data_dic.Exists(arr(i, 3)) Then
            Data_dic.Add arr(i, 3), 1
        Else
            Data_dic(arr(i, 3)) = Data_dic(arr(i, 3)) + 1
        End If
    Next i
    
    'giving the team with importances a dictionary key so all can be sorted to the top later
    If Not IsEmpty(arrSort) Then
        Dim aSortRank As Long
        For i = 1 To UBound(arr, 1)
            aSortRank = aSortNeed(arrSort, arr(i, 2))
            If aSortRank > 0 Then
                If Not hasImportance_dic.Exists(arr(i, 3)) Then
                    hasImportance_dic.Add arr(i, 3), aSortRank
                Else
                    hasImportance_dic(arr(i, 3)) = Application.WorksheetFunction.Min(aSortRank, hasImportance_dic(arr(i, 3)))
                End If
            End If
        Next i
    End If
    
    Dim arrSorted(), dict As Object
    ReDim arrSorted(1 To UBound(arr, 1), 1 To 4)
    arrSorted(1, 1) = Data_dic(arr(1, 3))
    For i = 1 To UBound(arr, 2) 'filling in the first spot of the sorted array
        arrSorted(1, i + 1) = arr(1, i)
    Next i
    For i = 2 To UBound(arr, 1) 'sorting the whole list and placing in front what grouping they belong to
        arrSorted = sortArr(arrSorted, arr(i, 1), arr(i, 2), arr(i, 3), arrSort, Data_dic(arr(i, 3)), i)
    Next i
    Data_dic.RemoveAll
    
    For i = 1 To UBound(arrSorted, 1) 'checking what the size of each group will be
        If Not Data_dic.Exists(arrSorted(i, 1)) Then
            Data_dic.Add arrSorted(i, 1), 1
        Else
            Data_dic(arrSorted(i, 1)) = Data_dic(arrSorted(i, 1)) + 1
        End If
    Next i
    
    Dim arrPrint
    Dim j As Long, currGr As Long, k As Long, p As Long
    j = 1
    For i = 1 To Data_dic.Count 'basically used for offset as well
        currGr = arrSorted(j, 1)
        ReDim arrPrint(1 To Data_dic(arrSorted(j, 1)), 1 To 3) 'print array needs to get the correct size
        p = 1
        Do While currGr = arrSorted(j, 1) 'filling the print array
            For k = 1 To 3
                arrPrint(p, k) = arrSorted(j, k + 1)
            Next k
            j = j + 1
            p = p + 1
            If j > UBound(arrSorted, 1) Then 'exiting while without throwing an error with the array boundries
                j = 1
                currGr = -1
            End If
        Loop
        ws.Range("A2").Offset(0, i * 3).Resize(UBound(arrPrint, 1), UBound(arrPrint, 2)).value = arrPrint 'printing per 3 columns
    Next i
    
    Set Data_dic = Nothing
    Set hasImportance_dic = Nothing
End Sub

Function sortArr(a, gr, name, team, aSort, amt, amtSorted) As Variant()
    Dim j As Long, Sorted As Boolean, recursiveNeeded As Boolean
    Dim temp1, temp2, temp3, temp4
    funcIteration = funcIteration + 1
    Debug.Print "Going into the function " & funcIteration
    If Not IsEmpty(aSort) Then
        j = 1
        Do While (j < amtSorted) And (Not recursiveNeeded)
            If amt < a(j, 1) Then 'grouping needs to come before the one we're comparing with
                recursiveNeeded = True
            Else
                If amt = a(j, 1) Then
                    If team = a(j, 4) Then
                        If aSortNeed(aSort, name) > 0 Then
                            If aSortNeed(aSort, a(j, 3)) > 0 Then
                                If aSortNeed(aSort, a(j, 3)) > aSortNeed(aSort, name) Then 'in case multiple sort-values are in the same team
                                    recursiveNeeded = True
                                End If
                            Else
                                recursiveNeeded = True
                            End If
                        Else
                            If (name < a(j, 3)) And (Not aSortNeed(aSort, a(j, 3)) > 0) Then
                                recursiveNeeded = True
                            End If
                        End If
                    Else
                        If hasImportance_dic.Exists(a(j, 4)) Then
                            If hasImportance_dic.Exists(team) Then
                                If hasImportance_dic(a(j, 4)) > hasImportance_dic(team) Then
                                    recursiveNeeded = True
                                ElseIf hasImportance_dic(a(j, 4)) = hasImportance_dic(team) And team < a(j, 4) Then
                                    recursiveNeeded = True
                                End If
                            End If
                        ElseIf hasImportance_dic.Exists(team) Then
                            recursiveNeeded = True
                        Else
                            If team < a(j, 4) Then
                                recursiveNeeded = True
                            End If
                        End If
                    End If
                End If
            End If
            If recursiveNeeded Then
                temp1 = a(j, 1)
                temp2 = a(j, 2)
                temp3 = a(j, 3)
                temp4 = a(j, 4)
                a(j, 1) = amt
                a(j, 2) = gr
                a(j, 3) = name
                a(j, 4) = team
                a = sortArr(a, temp2, temp3, temp4, aSort, temp1, amtSorted)
            End If
            j = j + 1
        Loop
    Else
        j = 1
        Do While j < amtSorted And Not recursiveNeeded
            If amt < a(j, 1) Then
                recursiveNeeded = True
            ElseIf amt = a(j, 1) Then
                If team = a(j, 4) Then
                    If name < a(j, 3) Then recursiveNeeded = True
                Else
                    If team < a(j, 4) Then recursiveNeeded = True
                End If
            End If
            If recursiveNeeded Then
                temp1 = a(j, 1)
                temp2 = a(j, 2)
                temp3 = a(j, 3)
                temp4 = a(j, 4)
                a(j, 1) = amt
                a(j, 2) = gr
                a(j, 3) = name
                a(j, 4) = team
                a = sortArr(a, temp2, temp3, temp4, aSort, temp1, amtSorted)
            End If
            j = j + 1
        Loop
    End If
    If Not recursiveNeeded Then
        a(j, 1) = amt
        a(j, 2) = gr
        a(j, 3) = name
        a(j, 4) = team
    End If
    sortArr = a
End Function

Function aSortNeed(aSort, val) As Long
    Dim k As Long
    For k = 1 To UBound(aSort, 1)
        If aSort(k, 1) = val Then
            aSortNeed = k
            Exit Function
        End If
    Next k
    aSortNeed = 0
End Function

字符串
希望它足够清楚，如果没有，请随时提问。我对结果很满意（不是它是如何编写的，而是让它/递归函数按预期工作，可能会在代码审查帖子中抛出这个，看看在某个时候可以做得更好）

编辑：

若要使没有值且包含空团队的分组出现在第一个分组中（没有重复团队），请仅调整主子组：

Sub RETEAM_FIXED()
    Dim Data_dic As Object
    Set Data_dic = CreateObject("Scripting.Dictionary")
    Set hasImportance_dic = CreateObject("Scripting.Dictionary")
    Dim lRow As Long, arr, lRowV As Long, arrSort, amtSorted As Long
    Dim ws As Worksheet
    
    Set ws = ActiveWorkbook.Worksheets("team0")
    lRow = ws.Range("B" & Rows.Count).End(xlUp).row
    ws.Range("D2:U" & lRow).ClearContents
    lRowV = ws.Range("V" & Rows.Count).End(xlUp).row
    arr = ws.Range("A2:C" & lRow).value
    If lRowV > 1 Then arrSort = ws.Range("V2:V" & lRowV).value
    
    Dim i As Long
    For i = 1 To UBound(arr, 1) 'counting the teams
        If Not Data_dic.Exists(arr(i, 3)) Then
            Data_dic.Add arr(i, 3), 1
        ElseIf Len(arr(i, 3)) > 0 Then
            Data_dic(arr(i, 3)) = Data_dic(arr(i, 3)) + 1
        End If
    Next i
    
    'giving the team with importances a dictionary key so all can be sorted to the top later
    If Not IsEmpty(arrSort) Then
        Dim aSortRank As Long
        For i = 1 To UBound(arr, 1)
            aSortRank = aSortNeed(arrSort, arr(i, 2))
            If aSortRank > 0 Then
                If Not hasImportance_dic.Exists(arr(i, 3)) Then
                    hasImportance_dic.Add arr(i, 3), aSortRank
                Else
                    hasImportance_dic(arr(i, 3)) = Application.WorksheetFunction.Min(aSortRank, hasImportance_dic(arr(i, 3)))
                End If
            End If
        Next i
    End If
    
    Dim arrSorted(), dict As Object
    ReDim arrSorted(1 To UBound(arr, 1), 1 To 4)
    arrSorted(1, 1) = Data_dic(arr(1, 3))
    For i = 1 To UBound(arr, 2) 'filling in the first spot of the sorted array
        arrSorted(1, i + 1) = arr(1, i)
    Next i
    For i = 2 To UBound(arr, 1) 'sorting the whole list and placing in front what grouping they belong to
        arrSorted = sortArr(arrSorted, arr(i, 1), arr(i, 2), arr(i, 3), arrSort, Data_dic(arr(i, 3)), i)
    Next i
    Data_dic.RemoveAll
    
    For i = 1 To UBound(arrSorted, 1) 'checking what the size of each group will be
        If Not Data_dic.Exists(arrSorted(i, 1)) Then
            Data_dic.Add arrSorted(i, 1), 1
        Else
            Data_dic(arrSorted(i, 1)) = Data_dic(arrSorted(i, 1)) + 1
        End If
    Next i
    
    Dim arrPrint
    Dim j As Long, currGr As Long, k As Long, p As Long
    Dim lastGrouping
    lastGrouping = arrSorted(UBound(arrSorted, 1), 1)
    j = 1
    For i = 1 To lastGrouping 'basically used for offset as well
        currGr = arrSorted(j, 1)
        If currGr <> i Then GoTo skipEmptyColumns
        ReDim arrPrint(1 To Data_dic(arrSorted(j, 1)), 1 To 3) 'print array needs to get the correct size
        p = 1
        Do While currGr = arrSorted(j, 1) 'filling the print array
            For k = 1 To 3
                arrPrint(p, k) = arrSorted(j, k + 1)
            Next k
            j = j + 1
            p = p + 1
            If j > UBound(arrSorted, 1) Then 'exiting while without throwing an error with the array boundries
                j = 1
                currGr = -1
            End If
        Loop
        ws.Range("A2").Offset(0, i * 3).Resize(UBound(arrPrint, 1), UBound(arrPrint, 2)).value = arrPrint 'printing per 3 columns
skipEmptyColumns:
    Next i
    
    Set Data_dic = Nothing
    Set hasImportance_dic = Nothing
End Sub

型
请注意，我重命名了子，所以现在不能有任何名称问题。这里有一个例子来展示它确实按预期工作：
x1c 0d1x的数据

Range（“G1：I9”）.Sort Key1：=Range（“H1”），Order1：= xl降序，Header：= xl是
V列中数据的排序不一定完全像我提到的那样。如果V的第一个值是110，第二个值是108，则排序将是不正确的。
as the picture shows