CMake能检测到我在C中使用pow时是否需要链接到libm吗？

0sgqnhkj 于 2023-10-16 发布在其他

关注(0)|答案(3)|浏览(121)

使用一些编译器，using pow and certain other functions in a C program requires linking to the m library。但是，有些编译器不需要这样做，并且在链接到m库时会出错。在C++中，std::thread和pthread存在几乎相同的情况，但CMake模块FindThreads完全消除了这一点-libm是否有类似的模块？
什么是最好的方法来检测与CMake做什么？这是我目前的解决方案，这是不太理想的，因为有更多的C编译器不仅仅是GCC和MSVC：

if(NOT MSVC)
    target_link_libraries(my-c-target PUBLIC m)
endif()

这符合我的目的，但我很确定在某些情况下它会失败，需要手动用户干预，这对不知道这种晦涩的人来说并不有趣。理想情况下，我不希望用户必须通过命令行指定他们的编译器是否是weird;我想在CMake中自动检测它，因为这是CMake的全部意义。

来源：https://stackoverflow.com/questions/32816646/can-cmake-detect-if-i-need-to-link-to-libm-when-using-pow-in-c

3条答案

按热度按时间

bvjxkvbb1#

您应该使用CHECK_FUNCTION_EXISTS命令来检查pow是否可以在没有附加标志的情况下使用。如果此检查失败，您可以将m库添加到CMAKE_REQUIRED_LIBRARIES变量，假设缺少的是针对libm的链接。但是您需要再次使用CHECK_FUNCTION_EXISTS来确保链接是足够的。
样本代码：

include(CheckFunctionExists)

if(NOT POW_FUNCTION_EXISTS AND NOT NEED_LINKING_AGAINST_LIBM)
  CHECK_FUNCTION_EXISTS(pow POW_FUNCTION_EXISTS)
  if(NOT POW_FUNCTION_EXISTS)
      unset(POW_FUNCTION_EXISTS CACHE)
      list(APPEND CMAKE_REQUIRED_LIBRARIES m)
      CHECK_FUNCTION_EXISTS(pow POW_FUNCTION_EXISTS)
      if(POW_FUNCTION_EXISTS)
          set(NEED_LINKING_AGAINST_LIBM True CACHE BOOL "" FORCE)
      else()
          message(FATAL_ERROR "Failed making the pow() function available")
      endif()
  endif()
endif()

if (NEED_LINKING_AGAINST_LIBM)
     target_link_libraries(your_target_here m)
endif()

赞(0）回复(0）举报 2023-10-16

fzwojiic2#

对于编译器来说，检查某些代码是否正确的常用方法是try_compile。

use_pow.c：

#include <math.h>
int main(void) {return pow(2, 2.5);}

CMakeLists.txt：

...
if(NOT DEFINED POW_LIBS)
    try_compile(pow_use_m # RESULT_VAR
                check_pow # bindir
                use_pow.c # srcfile
                LINK_LIBRARIES m)
    if(pow_use_m)
        set(POW_LIBS m CACHE INTERNAL "Libraries for use pow")
    else()
        set(POW_LIBS "" CACHE INTERNAL "Libraries for use pow")
    endif()
endif()

...
target_link_libraries(my-c-target PUBLIC ${POW_LIBS})

缓存条目POW_LIBS包含使用pow函数所需的库。

赞(0）回复(0）举报 2023-10-16

mlnl4t2r3#

如果我理解正确，链接libm总是首选的，如果它存在。
所以CheckLibraryExists可以用。

CMakeLists.txt

set(POW_LIBS "")
include(CheckLibraryExists)
check_library_exists(m pow "" LIBM)
if(LIBM)
    list(APPEND POW_LIBS "m")
endif()

...
target_link_libraries(${PROJECT_NAME} PUBLIC ${POW_LIBS})

已在Linux x86_64、glibc 2.23和cmake 3.13.2下测试

赞(0）回复(0）举报 2023-10-16

我来回答

CMake能检测到我在C中使用pow时是否需要链接到libm吗？

3条答案

相关问题

热门标签

最新问答