你不应该认为这是“浪费”RAM，真的。把它想象成“缓存”未使用的RAM。内存管理器持有未使用的内存而不是将其释放回操作系统是有原因的，事实上，您在问题中已经找到了这个原因。
你说你会在一个循环中重复运行相同的操作。当你这样做时，它仍然有旧的内存可用，它可以立即分配它，而不必向Windows请求新的堆块。这是将“Fast”置于“FastMM”中的技巧之一，如果它没有做到这一点，您会发现您的程序运行得更慢。
您不需要担心FastMM调试模式图。这只是为了调试，你不会发布一个针对FullslogMode编译的程序。而“不带FastMM”和“带FastMM发布模式”之间的差异约为1 MB，这在现代硬件上可以忽略不计。仅需额外增加1 MB的低成本，您就可以获得巨大的性能提升。所以别担心

使FastMM快速的部分原因是它将分配一大块内存，并从中分割出较小的统一大小的块。如果块的任何部分正在使用，则不能将其释放回操作系统。
您可以使用不同的内存管理器。一种方法是将所有分配直接路由到VirtualAlloc。分配将被舍入到一次占用整个页面，所以如果你有很多小的分配，你的程序可能会受到影响，但是当你调用VirtualFree时，你可以确信内存肯定不再属于你的程序了。
另一种选择是将所有内容路由到OS堆。使用HeapAlloc。你甚至可以为你的程序启用the low-fragmentation heap（在Windows Vista中默认为启用），这将使操作系统采用类似于FastMM使用的策略，但它将允许你使用微软的一些调试和分析工具来跟踪你的程序随着时间的推移的内存使用情况。但是要注意，在调用HeapFree之后，某些指标可能仍然显示内存属于程序。
此外，* 工作集 * 指的是 * 当前在物理RAM* 中的内存。你观察到的数字上升并不意味着你的程序已经分配了更多的内存。它可以简单地意味着你的程序“触及”了一些它以前分配的内存，但这些内存还没有放入RAM。在循环过程中，您触及了该内存，而操作系统尚未决定将其页出到磁盘。

我使用以下代码作为内存管理器。我这样做是因为它在线程争用下的性能比FastMM好得多，FastMM实际上相当差。我知道像Hoard这样的可伸缩管理器会更好，但这很适合我的需要。

unit msvcrtMM;

interface

implementation

type
  size_t = Cardinal;

const
  msvcrtDLL = 'msvcrt.dll';

function malloc(Size: size_t): Pointer; cdecl; external msvcrtDLL;
function realloc(P: Pointer; Size: size_t): Pointer; cdecl; external msvcrtDLL;
procedure free(P: Pointer); cdecl; external msvcrtDLL;

function GetMem(Size: Integer): Pointer;
begin
  Result := malloc(size);
end;

function FreeMem(P: Pointer): Integer;
begin
  free(P);
  Result := 0;
end;

function ReallocMem(P: Pointer; Size: Integer): Pointer;
begin
  Result := realloc(P, Size);
end;

function AllocMem(Size: Cardinal): Pointer;
begin
  Result := GetMem(Size);
  if Assigned(Result) then begin
    FillChar(Result^, Size, 0);
  end;
end;

function RegisterUnregisterExpectedMemoryLeak(P: Pointer): Boolean;
begin
  Result := False;
end;

const
  MemoryManager: TMemoryManagerEx = (
    GetMem: GetMem;
    FreeMem: FreeMem;
    ReallocMem: ReallocMem;
    AllocMem: AllocMem;
    RegisterExpectedMemoryLeak: RegisterUnregisterExpectedMemoryLeak;
    UnregisterExpectedMemoryLeak: RegisterUnregisterExpectedMemoryLeak
  );

initialization
  SetMemoryManager(MemoryManager);

end.

这不是对你问题的回答，但它太长了，不适合评论，你可能会发现在这个MM上运行你的应用很有趣。我的猜测是，它将执行相同的方式作为FastMM。

已解决

正如巴里凯利所建议的那样，FastaMM将自动释放内存。为了证实这一点，我创建了第二个程序，分配了大量的RAM。一旦Windows用完RAM，我的程序内存利用率就恢复到原来的值。
问题解决了谢谢，巴里。