让我们来看看Hakan的回答。如果你说在同一个字符串中可能有多个名字，例如。“Hello，my name is John and my姐妹篇name is Jane and we both likes fries”，如果您想提取键“name is“之后的所有名称，则可以使用此方法

WITH "name is " AS key 
MATCH (n:item) WHERE n.data CONTAINS key 
WITH key, n.data AS text, apoc.text.indexesOf(n.data, key) AS indexes 
UNWIND indexes AS index 
WITH key, text, index+size(key) AS nameindex 
RETURN substring(text, nameindex, apoc.text.indexOf(text, " ", nameindex)-nameindex)

一个警告是，如果文本末尾有一个名字，这个版本就不起作用了（因为它需要一个空格来跟随名字）。我也需要多想想怎么解决这个案子。
编辑：
下面这个版本也解决了这种特殊情况（一个名字出现在字符串的末尾，后面没有空格）：

WITH "name is " AS key 
MATCH (n:Person) WHERE n.data CONTAINS key 
WITH key, n.data AS text, apoc.text.indexesOf(n.data, key) AS indexes 
UNWIND indexes AS index 
WITH key, text, index+size(key) AS nameindex, apoc.text.indexOf(text, " ", index+size(key)) AS endindex
RETURN
CASE endindex
WHEN -1 THEN substring(text, nameindex)
ELSE substring(text, nameindex, endindex-nameindex)
END

顺便说一下，这需要你安装“APOC Core”库（它默认安装在Aura上，但如果你运行自己的示例，你需要安装它。只需将文件apoc-5.X.X-core.jar从labs文件夹移动到plugins文件夹，然后重新启动即可。

您可以利用核心APOC函数apoc.text.regexGroups来使用正则表达式，该正则表达式不区分大小写进行搜索，并忽略名称周围的非字母数字字符。举例来说：

UNWIND [
    "Hello my name is Sally and I really could go for some fries right now. Did I mention that my name is Sally?",
    "My name is Waldo but sometimes I say my name is Charlie, and sometimes I say my name is **Fido**. Arf!"
] AS s

UNWIND apoc.text.regexGroups(s, '(?i)my name is \W*(\w+)') AS group
RETURN s, apoc.coll.flatten(COLLECT(TAIL(group))) AS names

返回：

╒═══════════════════════════════════════╤════════════════════════════╕
│s                                      │names                       │
╞═══════════════════════════════════════╪════════════════════════════╡
│"Hello my name is Sally and I really co│["Sally", "Sally"]          │
│uld go for some fries right now. Did I │                            │
│mention that my name is Sally?"        │                            │
├───────────────────────────────────────┼────────────────────────────┤
│"My name is Waldo but sometimes I say m│["Waldo", "Charlie", "Fido"]│
│y name is Charlie, and sometimes I say │                            │
│my name is **Fido**. Arf!"             │                            │
└───────────────────────────────────────┴────────────────────────────┘

如果你希望文本以你的文本片段开始，你可以这样做：

UNWIND [
    "Hello my name is Sally and I really could go for some fries right now",
    "Hello my name is Ben and I really could go for a burger right now"
] AS text
WITH text, "Hello my name is" as q
WHERE text starts with q
RETURN trim(right(text, size(text)-size(q)))

如果你只希望文本包含文本片段，你需要使用apoc.text.indexOf：

UNWIND [
    "Hello my name is Sally and I really could go for some fries right now",
    "Hello my name is Ben and I really could go for a burger right now"
] AS text
WITH text, "my name is" as q
WHERE text contains q
RETURN trim(right(text, size(text)-apoc.text.indexOf(text,q)-size(q)))