对于CMake 3.18或更新版本，请使用ARCHIVE_CREATE file命令。它支持创建zip和7zip存档。
例如，如果当前CMake源目录包含文件testfile.txt和目录testdir，则可以使用以下CMake命令创建包含这两项的zip文件：

file(ARCHIVE_CREATE
    OUTPUT "archive.zip"
    PATHS 
        "${CMAKE_CURRENT_SOURCE_DIR}/testfile.txt"
        "${CMAKE_CURRENT_SOURCE_DIR}/testdir"
    FORMAT "zip")

对于早期版本的CMake（3.2 - 3.17），请使用CMake命令行模式子命令tar：

add_custom_target(create_zip COMMAND
    ${CMAKE_COMMAND} -E tar "cfv" "archive.zip" --format=zip
       "${CMAKE_CURRENT_SOURCE_DIR}/testfile.txt"
       "${CMAKE_CURRENT_SOURCE_DIR}/testdir")

对于CMake 3.2之前的版本，您可以使用jar命令，该命令是标准Java JRE安装的一部分。

find_package(Java)

execute_process(
    COMMAND
        "${Java_JAR_EXECUTABLE}" "cfM" "archive.zip" 
        "-C" "${CMAKE_CURRENT_SOURCE_DIR}" "testfile.txt" 
        "-C" "${CMAKE_CURRENT_SOURCE_DIR}" "testdir"
    RESULT_VARIABLE _result
)

zip文件将在当前CMake二进制目录（CMAKE_CURRENT_BINARY_DIR）中生成。

告诉你真实的答案永远不会晚：

function(create_zip output_file input_files working_dir)
    add_custom_command(
        COMMAND ${CMAKE_COMMAND} -E tar "cf" "${output_file}" --format=zip -- ${input_files}
        WORKING_DIRECTORY "${working_dir}"
        OUTPUT  "${output_file}"
        DEPENDS ${input_files}
        COMMENT "Zipping to ${output_file}."
    )
endfunction()

使用相同

file(GLOB ZIP_FILES "${CMAKE_CURRENT_SOURCE_DIR}/zip/*")
create_zip("${CMAKE_CURRENT_BINARY_DIR}/native_data.zip" "${ZIP_FILES}" "${CMAKE_CURRENT_SOURCE_DIR}/zip")

这将把zip/中的所有文件打包到native_data.zip中（在构建目录中）。然后包括您的存档（路径将在不同的CMakeLists.txt不同！）作为源文件或将其添加为目标文件：

add_custom_target("project-data" ALL DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/native_data.zip")

安装将不会有很大的不同，从平常：

install(FILES "${CMAKE_CURRENT_BINARY_DIR}/native_data.zip" DESTINATION ${DATADIR} RENAME "data000.zip") # Install our zip (as data000.zip)

我假设你已经安装了一个压缩工具（WinZip或7z等）。你可以写一个find_zip-tool脚本来搜索WinZip或7Z等。
WinZip的嗅探器：

FIND_PROGRAM(ZIP_EXECUTABLE wzzip PATHS "$ENV{ProgramFiles}/WinZip")
IF(ZIP_EXECUTABLE)
  SET(ZIP_COMMAND "\"${ZIP_EXECUTABLE}\" -P \"<ARCHIVE>\" @<FILELIST>")
ENDIF(ZIP_EXECUTABLE)

7-zip的嗅探器：

FIND_PROGRAM(ZIP_EXECUTABLE 7z PATHS "$ENV{ProgramFiles}/7-Zip") 
  IF(ZIP_EXECUTABLE)
    SET(ZIP_COMMAND "\"${ZIP_EXECUTABLE}\" a -tzip \"<ARCHIVE>\" @<FILELIST>")
  ENDIF(ZIP_EXECUTABLE)

看一下档案

<cmake-install-dir>\share\cmake-2.8\Modules\CPackZIP.cmake

它展示了CPack如何搜索Zip_Executable并准备一些“有用的”默认标志。
之后，我建议使用execute_process，类似于sakra的答案

从3.18版开始，CMake现在直接支持使用file()命令和ARCHIVE_CREATE创建zip或归档文件：

file(ARCHIVE_CREATE OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/MyData.zip
    PATHS ${CMAKE_CURRENT_SOURCE_DIR}/data
    FORMAT zip
)

请确保为OUTPUT压缩文件名指定完整路径，否则可能无法生成文件。此外，PATHS选项接受将 files 或 directories 放置在zip文件中，但在编写时不接受通配符。
此命令支持多种存档格式和压缩风格。因此，您也可以使用相同的命令来创建tarball：

file(ARCHIVE_CREATE OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/MyData.tar.gz
    PATHS ${CMAKE_CURRENT_SOURCE_DIR}/data
    FORMAT gnutar
    COMPRESSION GZip
)

由于这是使用CMake创建zip文件的最佳搜索结果，因此这里有一个完整的CPack解决方案。基本思想是调用install()，然后告诉它如何命名生成的zip文件。它将被放置在构建目录中，尽管可能有一种方法可以改变这一点。然后您可以使用make package或cpack创建zip文件。

# Version 1: Subtractive
# Include everything in the project source directory.
# Put it at the top level of the zip via `DESTINATION .`
# Subtract things we don't want.
# The trailing slash after "${PROJECT_SOURCE_DIR}/" prevents
# an extra layer of directories.
install(DIRECTORY "${PROJECT_SOURCE_DIR}/"
    DESTINATION .
    PATTERN ".git*" EXCLUDE
    PATTERN ".DS_Store" EXCLUDE
    PATTERN "examples" EXCLUDE
    PATTERN "docs" EXCLUDE
    PATTERN "README.md" EXCLUDE
)

# Version 2: Additive
# Include only the list of things we specify.
# Put it at the top level of the zip via `DESTINATION .`
# install(FILES
#     ${SRCS}
#     "Notes.txt"
#     DESTINATION .
# )

# Tell CPack to create a zip file.
set(CPACK_GENERATOR "ZIP")
# Tell CPack what to name the zip file. It will append `.zip`.
set(CPACK_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}")
# Tell CPack not to put everything inside an enclosing directory.
set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY OFF)
# Apparently this should be always on but isn't for backwards compatibility.
set(CPACK_VERBATIM_VARIABLES YES)
include(CPack)

本质上我做的是创建自定义目标

add_custom_target(STAGE_FILES)

使用此目标，我将文件和目录复制到CMAKE_CURRENT_BINARY_DIR

add_custom_command( 
  TARGET STAGE_FILES 
  COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/assets/video ${CMAKE_CURRENT_BINARY_DIR}/video
  COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/assets/data ${CMAKE_CURRENT_BINARY_DIR}/data
  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_SOURCE_DIR}/assets/strings_en.csv ${CMAKE_CURRENT_BINARY_DIR}/
  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_SOURCE_DIR}/assets/strings_rules_en.csv ${CMAKE_CURRENT_BINARY_DIR}/
  COMMAND ${CMAKE_COMMAND} -E tar "cfv" "data.zip" --format=zip  --files-from=${CMAKE_SOURCE_DIR}/assets/to_zip.txt
  COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_CURRENT_BINARY_DIR}/data
  COMMAND ${CMAKE_COMMAND} -E rename  ${CMAKE_CURRENT_BINARY_DIR}/data.zip ${CMAKE_CURRENT_BINARY_DIR}/data
)

重要线路

COMMAND ${CMAKE_COMMAND} -E tar "cfv" "data.zip" --format=zip  --files-from=${CMAKE_SOURCE_DIR}/assets/to_zip.txt

在我
to_zip.txt
我指定所有的文件，我想包括在我的压缩

data/
video/
...

我现在可以执行命令

make STAGE_FILES

这将复制和压缩我需要的一切