awk -F@ -v OFS= '
    # process the substitution table
    NR==FNR {
        # if it looks like a key/value pair, save it
        if (i=index($0,"="))
            a[ substr($0,1,i-1) ] = substr($0,i+1)
        # else warn about invalid line

        next
    }

    # process the template
    {
        # line has been split into fields on "@"
        # "@" come as pairs, so even fields are keys

        # warn if NF%2 != 0

        # do the substitutions
        # undefined keys are replaced with ""
        # check key exists if that is not wanted
        for (i=2; i<=NF; i+=2)
            $i=a[$i]

        print
    }
' testfile2.txt testfile1.txt

不要在 every=字符处拆分输入，而是以不同的方式提取键和值。
可能的解决办法（除其他外）

awk 'FNR==NR{key=val=$0;sub(/=.*/,"",key);sub(/[^=]*=/,"",val);a[key]=val; next}
match($0, "@[^@]*@"){
        i=substr($0, RSTART+1, RLENGTH-2 "@");
        gsub("@"i"@", a[i]);  }1 ' testfile2.txt testfile1.txt

文件分隔符FS设置为=，testfile2.txt 有2个等号，这就是为什么您在输出中缺少第三部分，因为您只使用$2
你可以做的是删除FS==，因为你不需要 testfile1.txt，并在一个更具体的字符串_path=上分割 testfile2.txt

awk 'FNR==NR{
  split($0, p, "_path=")
  a[p[1] "_path"] = p[2]
  next
} 
match($0, "@[^@]*@"){
  i = substr($0, RSTART+1, RLENGTH-2 "@");
  gsub("@"i"@", a[i]);  
}1 ' testfile2.txt testfile1.txt

输出

# START :: start of file ##
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
#
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
## END :: end of file ##

假设条件：

• 如果@some_pattern_to_match@不匹配，则保持原样

向testfile1.txt添加一个不匹配的条目（请参阅最后一行旁边的内容）：

$ cat testfile1.txt
## START :: start of file ##
[email protected]_path@
#
[email protected]_brkr_path@
#
[email protected]_path@
#
[email protected]_brkr_path@
#
path.mw.[email protected]_MATCH@
## END :: end of file ##

awk：

awk '
FNR==NR { if ( n=index($0,"=") )                        # 1st file: if line includes a "=" then ...
             a[ substr($0,1,n-1) ] = substr($0,n+1)     # split and save as array index and value
          next
        }

# 2nd file: split on "@" and if we get 3 fields and the 2nd field is an index in array a[] then rewrite current line

split($0,x,"@")==3 && x[2] in a { $0 = x[1] a[x[2]] }

1                                                       # 2nd file: print current line
' testfile2.txt testfile1.txt

这产生：

## START :: start of file ##
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
#
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
#
path.mw.[email protected]_MATCH@
## END :: end of file ##

为什么不使用sed：

sed 's/=/@^/; s/^/s^@/; s/$/^g/' testfile2.txt | sed -f- testfile1.txt

输出量：

## START :: start of file ##
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
#
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
## END :: end of file ##

$ awk -F'=' -v OFS='=' '
       NR==FNR{
               key="@"$1"@"; 
               sub(/^[^=]*=/,""); 
               a[key]=$0; 
               next
       } 
       $2 in a { $2=a[$2] }1
' testfile2.txt testfile1.txt 

## START :: start of file ##
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
#
path.mw.site.profiles=/mw/mysite/cfg/DATA1/
#
path.mw.site.broker.profiles=/usr/local/mw/mysite/cfg/DATA2/=/mydirectory/
## END :: end of file ##