假设：

• 一个+只显示在第3/第4字段，然后只在前面的电话号码

一种awk方法：

awk '
BEGIN { FS=OFS="+" }                               # split input on "+"
      { for (i=2; i<=NF; i++) {                    # loop through fields that start with a phone number
            oldfld = $i                            # save current field
            $i = ""                                # initialize new field
            d1 = substr(oldfld,1,1)                # get 1st digit
            len = (d1 == 1 ? 7 : 6)                # determine length of phone prefix
            $i = substr(oldfld,1,len)              # save everything up to the phone prefix

            for (j=(len+1); j<=(len+4); j++) {     # loop through last 4 digits of phone number
                x = substr(oldfld,j,1)             # get current digit
                $i = $i (x==9 ? 0 : x+1)           # increment and add to new field
            }

            $i = $i substr(oldfld,len+4+1)         # save rest of old field
         }
      }
1                                                  # print current line
' test.txt

字符串
这将产生：

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

型

使用gnu-awk，你可以这样做：

awk '
function repl(s,  i, r, ch) {
   for (i=1; i<=length(s); ++i) {
      ch = substr(s,i,1)
      r = r (ch == 9 ? 0 : ch+1)
   }
   return r
}
BEGIN {FS=OFS="+"}
{
   for (j=2; j<=NF; ++j) {
      if (match($j, /^([0-9]+)([0-9]{4})(0x|[^x0-9]|$)(.*)/, a))
         $j = a[1] repl(a[2]) a[3] a[4]
   }
} 1' file

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
67|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

字符串

使用GNU awk for the 3rd arg to match（）：

$ awk '{
    head = ""
    while ( match($0,/([^+]+\+[0-9]{7})([0-9]{4})/,a) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr(a[2],i,1) + 1) % 10)
        }
        head = head a[1] digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt
69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

字符串
这会产生预期的输出，而不需要测试第3个或第4个字段，也不需要测试0x，因为除了3或4之外，没有匹配目标regexp的字段中的字符串，尽管您说过忽略0后跟x，实际上，你只是一直在改变前11位数字，任何0后面跟着x就是第12位数字。
你可以使用任何POSIX awk来做同样的事情：

awk '{
    head = ""
    while ( match($0,/\+[0-9]{11}/) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr($0,RSTART+RLENGTH-5+i,1) + 1) % 10)
        }
        head = head substr($0,1,RSTART+RLENGTH-5) digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt

型