delphi 如何在TImage控件中加载和显示tiff图像？

ars1skjm 于 2023-11-18 发布在其他

关注(0)|答案(4)|浏览(182)

我目前正在 Delphi XE 2试用版上工作。我想在不使用任何第三方组件/库的情况下在TIMage控件中加载和显示TIFF图像。
我尝试了下面的代码，但它不适合我。

Procedure TForm1.Button1Click(Sender: TObject); 
Var 
     OleGraphic               : TOleGraphic; 
     fs                       : TFileStream; 
     Source                   : TImage; 
     BMP                      : TBitmap; 
Begin 
     Try 
          OleGraphic := TOleGraphic.Create; 

          fs := TFileStream.Create('c:\testtiff.dat', fmOpenRead Or fmSharedenyNone); 
          OleGraphic.LoadFromStream(fs); 

          Source := Timage.Create(Nil); 
          Source.Picture.Assign(OleGraphic); 

          BMP := TBitmap.Create; 
          bmp.Width := Source.Picture.Width; 
          bmp.Height := source.Picture.Height; 
          bmp.Canvas.Draw(0, 0, source.Picture.Graphic); 

          image1.Picture.Bitmap := bmp;
     Finally 
          fs.Free; 
          OleGraphic.Free; 
          Source.Free; 
          bmp.Free; 
     End; 
End;

字符串
还请多多指教。

delphi

来源：https://stackoverflow.com/questions/7845359/how-to-load-and-display-tiff-images-in-timage-control

4条答案

按热度按时间

iecba09b1#

tiff := TWICImage.Create;
     tiff.LoadFromFile(Filename);
     ABitmap.Assign(tiff);

字符串

赞(0）回复(0）举报 2023-11-18

bbuxkriu2#

可以使用GDI+：

uses ..., ActiveX, GDIPAPI, GDIPOBJ, GDIPUTIL;

function LoadImageFromFile(const FileName: string; Bmp: TBitmap): Boolean;
var
  GPImage: TGPImage;
  encoderClsid: TGUID;
  MemStream: TMemoryStream;
begin
  Result := False;
  GPImage := TGPImage.Create(FileName);
  try
    if GPImage.GetLastStatus = Ok then
    begin
      MemStream := TMemoryStream.Create;
      try
        GetEncoderClsid('image/bmp', encoderClsid);
        if GPImage.Save(TStreamAdapter.Create(MemStream), encoderClsid) = Ok then
        begin
          MemStream.Position := 0;
          Bmp.LoadFromStream(MemStream);
          Result := True;
        end;
      finally
        MemStream.Free;
      end;
    end;
  finally
    GPImage.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  LoadImageFromFile('D:\ML_10222.tif', Image1.Picture.Bitmap);
end;

字符串
我还想提一下Synopsys TSynPicture（GDI+ wrapper）：https://stackoverflow.com/a/6251810/937125

**编辑：**GDI+ TGPImage也支持多个tiff帧/页面：

要获取帧数，请使用用途：

GPImage.GetFrameCount(GDIPAPI.FrameDimensionPage);

型
要设置活动帧，用途：

GPImage.SelectActiveFrame(GDIPAPI.FrameDimensionPage, Index);

型
注意TSynPicture也支持多帧。

赞(0）回复(0）举报 2023-11-18

dzhpxtsq3#

正如我在评论中所说，如果文件扩展名是标准的tiff扩展名，则打开文件的代码是微不足道的：

image1.Picture.LoadFromFile(MyTiffFile);

字符串
如果没有，请遵循dwrbudr的答案。
下面是一个示例：

procedure LoadBitmapFromFile( aImage : TImage; tiffFilename : String);
var
  tiffIm : TWICImage;
  ext : String;
begin
  ext := SysUtils.ExtractFileExt(tiffFilename);
  if (ext = '.tif') or (ext = '.tiff')
    then aImage.Picture.LoadFromFile(tiffFilename)
    else begin
      tiffIm:= TWICImage.Create;
      try
        tiffIm.LoadFromFile(tiffFilename);
        aImage.Picture.Bitmap.Assign(tiffIm);
      finally
        tiffIm.Free;
      end;
    end;
end;

型
另请参阅TWICImage，适用于XP SP3及更高版本。

赞(0）回复(0）举报 2023-11-18

nvbavucw4#

另外，如果TIF包含多张图片，您可以在TWicImage中加载图片之前，使用FrameIndex属性指定要加载的图片
使用FrameCount，您可以获得TIF文件中可用图像的数量
FrameIndex范围为0到FrameCount-1

赞(0）回复(0）举报 2023-11-18