符号引用（使用变量名作为引用）只适用于包变量。而且这是一个非常糟糕的主意，这就是为什么我们总是使用use strict;来防止我们自己使用它们（以及其他一些原因）。
一个解决方案：

my %vars = (
   parameters => {
      ReferenceCode => '00000',
   },
);

my $template = q{$parameters{'ReferenceCode'}};

my $output = $template =~ s{
   \$(\w+)\{'(\w+)'\}
}{
   exists( $vars{ $1 } ) && exists( $vars{ $1 }{ $2 } ) 
   ? $vars{ $1 }{ $2 }
   : $&
}xegr;

字符串
请注意，您的模板系统没有任何形式的转义，这是有问题的。您是否考虑过使用现有的模板系统，而不是重新发明轮子？

use Template qw( );

my %vars = (
   parameters => {
      ReferenceCode => '00000',
   },
);

my $template = q{[% parameters.ReferenceCode %]};

my $tt = Template->new();
$tt->process( \$template, \%vars, my $output)
   or die( $tt->error() );

型

使用e或ee标志，如下所示。
但是要注意使用eval是不安全的。考虑只传递用户输入的键，而不是整个perl变量（或任何代码）：

use strict;
use warnings;

my %parameters = ( 'ReferenceCode', 00000 );

my $string;

$string = q\$parameters{'ReferenceCode'}\;
$string =~ s/\$(\w+)\{'(\w+)'\}/$&/eg;
print("$string\n");
# $parameters{'ReferenceCode'}

$string = q\$parameters{'ReferenceCode'}\;
$string =~ s/\$(\w+)\{'(\w+)'\}/$&/eeg;
print("$string\n");
# 0

字符串
这些标志用于：
/e：将REPLACEMENT作为s/PATTERN/REPLACEMENT/中的表达式求值
/ee：将REPLACEMENT作为字符串求值，然后将结果eval。