你的代码是不必要的复杂，即使是老的 Delphi 版本。为什么要获取流的字符串版本强制重新分配流的内存呢？

function MemoryStreamToString(M: TMemoryStream): string;
begin
  SetString(Result, PChar(M.Memory), M.Size div SizeOf(Char));
end;

字符串
这适用于所有 Delphi 版本，而不仅仅是 Delphi 2009。它在流为空时工作，没有任何特殊情况。SetString是一个被低估的函数。
如果切换到 Delphi 2009后流的内容没有更改为Unicode，那么你应该使用这个函数：

function MemoryStreamToString(M: TMemoryStream): AnsiString;
begin
  SetString(Result, PAnsiChar(M.Memory), M.Size);
end;

型
这与您的原始代码等效，但跳过了特殊情况。

或者你可以重构你的代码来直接使用TStringStream？你可以使用它来代替TMemoryStream（它们有相同的接口），你可以通过简单地调用myString：= myStringStream.DataString;

一个“更干净”的方法可能是：

function StreamToString(aStream: TStream): string;
var
  SS: TStringStream;
begin
  if aStream <> nil then
  begin
    SS := TStringStream.Create('');
    try
      SS.CopyFrom(aStream, 0);  // No need to position at 0 nor provide size
      Result := SS.DataString;
    finally
      SS.Free;
    end;
  end else
  begin
    Result := '';
  end;
end;

字符串

我用途：

function StreamToString(const Stream: TStream; const Encoding: TEncoding): string;
var
  StringBytes: TBytes;
begin
  Stream.Position := 0;
  SetLength(StringBytes, Stream.Size);
  Stream.ReadBuffer(StringBytes, Stream.Size);
  Result := Encoding.GetString(StringBytes);
end;

字符串
它已经测试了 Delphi XE7只。

我还没有升级，但我的理解是：

NewCapacity := (M.Size + 1) * SizeOf(Char);

字符串

有一个名为TStringStream的因子可以帮助你.你可以像这样加载另一个流的内容：

var StringStream: TStringStream; 
begin StringStream := TStringStream.Create(''); 
StringStream.CopyFrom(OtherStream, OtherStream.Size); 
end;

字符串
你现在可以进入一个String类型的序列，比如：data-string属性包含了序列.但是不要尝试使用大对象，比如你加载一个巨大的文件到一些文件列表中，然后将其复制到你自己的stringstream中，并努力产生它，因为它会占用很多内存！
希望有帮助

你可以把它转换成正确大小的字符指针，然后简单地赋值：

procedure getMemoryStreamAsString( aMS_ : TMemoryStream );
var
  ws : widestring; // in newer Delphi it can be string
  ans : ansistring;
begin
  ws := pwidechar( aMS_.memory );
  // OR
  ans := pansichar( aMS_.memory );
end;

字符串

使用良好的旧StringList

function StreamToString (Stream : TStream; Encoding : TEncoding) : string;
begin
  var List := TStringList.Create;
  try
    List.LoadFromStream (Stream, Encoding);
    Result := List.Text;
  finally
    List.Free;
  end; 
end;

字符串