实际上，对于LMC，在SUB之后立即执行ADD是不好的，因为这会影响累加器上的负标志 * 和 *。（取决于模拟器），SUB之后的累加器值也没有定义，尽管大多数LMC模拟器将使用模运算（或将允许累加器实际上具有负值），但不能依赖于此行为。
解决方法是先用BRP检查SUB是否在零以下溢出，然后--如果溢出了--在减法完成之前 * 用原始值再次加载累加器。这是最可靠的方法（就代码的可移植性而言）。
其他一些评论：

• 当BRZ紧跟在BRP之后时，BRZ几乎没有意义，因为当累加器的值为零时，后者也将分支。
• 标签的名称out是不明确的：一些LMC模拟器可能会将其解释为指令OUT，并且无法解析程序。
• 名称r，t，x，y，cnt，.等不是很有描述性。我不会重复任何东西，只是使用更长的标签：这将提高代码的可读性。
• 我不会在除法过程中重复将余数加到当前值上（在x中），因为在大多数情况下余数将为0。您可以在执行最后一次减法的情况下（y情况）这样做，然后将其重置为零，并执行除法循环的一次迭代（因为现在当前值可能在3和5之间）。
• 如果将x和y的块交换，则可以保存一条BR指令。

这里是修改后的代码-你可以在这里运行它：

#input: 4 4 2
           LDA zero
           STO remainder
           STO average
           LDA three
           STO inputcount
getnext    IN
           STO value
divide     LDA value
           SUB three
           BRP positive
           LDA remainder # ignore the subtraction of 3
           BRZ continue  # branch if no remainder
           ADD value # now we have no problem with NEG flag
           STO value # remainder is added
           LDA zero
           STO remainder
           BR  divide # repeat one more time
positive   STO value
           LDA average
           ADD one
           STO average
           BR  divide
continue   LDA value
           STO remainder
           LDA inputcount
           SUB one
           STO inputcount
           BRZ output
           BR  getnext
output     LDA average
           OUT
           HLT
value      DAT 0
average    DAT 0
inputcount DAT 3
remainder  DAT 0
zero       DAT 0
one        DAT 1
three      DAT 3


<script src="https://cdn.jsdelivr.net/gh/trincot/[email protected]/lmc.js"></script>

字符串